Support for automake and VC++ builds

1 files changed, 60 insertions, 0 deletions

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..612cdfc
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,60 @@
+# file      : configure.ac
+# author    : Boris Kolpackov <boris@codesynthesis.com>
+# copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+# license   : GNU GPL v2; see accompanying LICENSE file
+
+AC_PREREQ(2.60)
+AC_INIT([libodb-mysql], [__value__(version)], [odb-users@codesynthesis.com])
+AC_CONFIG_AUX_DIR([config])
+AC_CONFIG_MACRO_DIR([m4])
+AC_CONFIG_SRCDIR([odb/mysql/version.hxx])
+
+AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects dist-bzip2 dist-zip tar-ustar])
+
+LT_INIT([win32-dll])
+
+AC_CANONICAL_HOST
+
+# Check for C++ compiler and use it to compile the tests.
+#
+AC_PROG_CXX
+AC_LANG(C++)
+
+# Required by subdir-objects.
+#
+AM_PROG_CC_C_O
+
+# Create the libtool executable so that we can use it in further tests.
+#
+LT_OUTPUT
+
+# Check for threads.
+#
+THREADS
+
+# Check for libmysqlclient.
+#
+LIBMYSQLCLIENT(
+  [$threads],
+  [],
+  [AC_MSG_ERROR([lib$libmysqlclient_name is not found; consider using CPPFLAGS/LDFLAGS to specify its location])])
+
+# Check for libodb.
+#
+LIBODB([],[AC_MSG_ERROR([libodb is not found; consider using --with-libodb=DIR])])
+
+# Allow the user to specify the pkgconfig directory.
+#
+PKGCONFIG
+
+# Check if we should disable rpath.
+#
+DISABLE_RPATH
+
+# Output.
+#
+AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_FILES([
+  __path__(config_files)
+])
+AC_OUTPUT