blob: f68a1df3b8339016323ad76610f581660e91f1c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
@echo off
rem file : build.bat
rem copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
rem license : GNU GPL v2; see accompanying LICENSE file
rem
rem build.bat database vc-version conf plat [/Build|/Clean|/Rebuild]
rem
rem conf: {Debug,Release}|all
rem plat: {Win32,x64}|all
rem
setlocal
if "_%1_" == "__" (
echo no database specified
goto usage
)
if "_%2_" == "__" (
echo no VC++ version specified
goto usage
)
if "_%~3_" == "__" (
echo no configuration specified
goto usage
)
if "_%~4_" == "__" (
echo no platform specified
goto usage
)
set "failed="
if "_%2_" == "_9_" set "vcver=9"
if "_%2_" == "_10_" set "vcver=10"
if "_%vcver%_" == "__" (
echo unknown VC++ version %2
goto usage
)
set "confs=%~3"
set "plats=%~4"
if "_%confs%_" == "_all_" set "confs=Debug Release"
if "_%plats%_" == "_all_" set "plats=Win32 x64"
set "action=%5"
if "_%action%_" == "__" set "action=/Build"
set "devenv=%DEVENV%"
if "_%devenv%_" == "__" set "devenv=devenv.com"
goto start
rem
rem %1 - solution name
rem %2 - configuration to build
rem %3 - platform to build
rem
:run_build
echo.
echo building %1 %3 %2
"%devenv%" %1 %action% "%2|%3" 2>&1
if errorlevel 1 set "failed=%failed% %1\%3\%2"
goto :eof
:start
for %%d in (libodb libodb-%1 libodb-boost libodb-qt) do (
for %%c in (%confs%) do (
for %%p in (%plats%) do (
call :run_build %%d/%%d-vc%vcver%.sln %%c %%p
)
)
)
if not "_%failed%_" == "__" goto error
for %%c in (%confs%) do (
for %%p in (%plats%) do (
call :run_build odb-examples-%1/examples-%1-vc%vcver%.sln %%c %%p
)
)
if not "_%failed%_" == "__" goto error
for %%c in (%confs%) do (
for %%p in (%plats%) do (
call :run_build odb-examples-%1/boost/boost-%1-vc%vcver%.sln %%c %%p
)
)
if not "_%failed%_" == "__" goto error
for %%c in (%confs%) do (
for %%p in (%plats%) do (
call :run_build odb-examples-%1/qt/qt-%1-vc%vcver%.sln %%c %%p
)
)
if not "_%failed%_" == "__" goto error
cd odb-tests-%1
call build.bat %1 %2 %3 %4 %action%
if errorlevel 1 (
cd ..
goto error
)
cd boost
call build.bat %1 %2 %3 %4 %action%
if errorlevel 1 (
cd ..\..
goto error
)
cd ..\qt
call build.bat %1 %2 %3 %4 %action%
if errorlevel 1 (
cd ..\..
goto error
)
echo.
echo ALL BUILDS SUCCEEDED
echo.
goto end
:usage
echo.
echo usage: build.bat database vc-version conf plat [action]
echo valid configurations are: {Debug,Release}|all
echo valid platforms are: {Win32,x64}|all
echo valid actions are: /Build (default), /Clean, and /Rebuild
echo.
:error
if not "_%failed%_" == "__" (
echo.
for %%t in (%failed%) do echo FAILED: %%t
echo.
)
endlocal
exit /b 1
:end
endlocal
|
