aboutsummaryrefslogtreecommitdiff
path: root/m4
diff options
context:
space:
mode:
Diffstat (limited to 'm4')
-rw-r--r--m4/acx-pthread.m4254
-rw-r--r--m4/database.m441
-rw-r--r--m4/diff.m455
-rw-r--r--m4/libodb-mysql.m484
-rw-r--r--m4/libodb-tracer.m484
-rw-r--r--m4/libodb.m483
-rw-r--r--m4/libtool-link.m431
-rw-r--r--m4/mysql.m4270
-rw-r--r--m4/odb.m445
-rw-r--r--m4/static-lib.m419
-rw-r--r--m4/threads.m441
11 files changed, 1007 insertions, 0 deletions
diff --git a/m4/acx-pthread.m4 b/m4/acx-pthread.m4
new file mode 100644
index 0000000..feeb01d
--- /dev/null
+++ b/m4/acx-pthread.m4
@@ -0,0 +1,254 @@
+dnl
+dnl NOTE: This file was modified. See the comments starting with 'CS:'
+dnl for more information. In particular, it was changed to use C++
+dnl instead of C.
+dnl
+dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl @summary figure out how to build C++ programs using POSIX threads
+dnl
+dnl This macro figures out how to build C++ programs using POSIX threads.
+dnl It sets the PTHREAD_LIBS output variable to the threads library and
+dnl linker flags, and the PTHREAD_CXXFLAGS output variable to any special
+dnl C++ compiler flags that are needed. (The user can also force certain
+dnl compiler flags/libs to be tested by setting these environment
+dnl variables.)
+dnl
+dnl Also sets PTHREAD_CXX to any special C++ compiler that is needed for
+dnl multi-threaded programs (defaults to the value of CXX otherwise).
+dnl (This is necessary on AIX to use the special xlC_r compiler alias.)
+dnl
+dnl NOTE: You are assumed to not only compile your program with these
+dnl flags, but also link it with them as well. e.g. you should link
+dnl with $PTHREAD_CXX $CXXFLAGS $PTHREAD_CXXFLAGS $LDFLAGS ... $PTHREAD_LIBS
+dnl $LIBS
+dnl
+dnl If you are only building threads programs, you may wish to use
+dnl these variables in your default LIBS, CXXFLAGS, and CXX:
+dnl
+dnl LIBS="$PTHREAD_LIBS $LIBS"
+dnl CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+dnl CXX="$PTHREAD_CXX"
+dnl
+dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
+dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
+dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
+dnl
+dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
+dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
+dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
+dnl default action will define HAVE_PTHREAD.
+dnl
+dnl Please let the authors know if this macro fails on any platform, or
+dnl if you have any other suggestions or comments. This macro was based
+dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
+dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
+dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
+dnl We are also grateful for the helpful feedback of numerous users.
+dnl
+dnl @category InstalledPackages
+dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
+dnl @version 2006-05-29
+dnl @license GPLWithACException
+
+AC_DEFUN([ACX_PTHREAD], [
+AC_REQUIRE([AC_CANONICAL_HOST])
+AC_LANG_SAVE
+AC_LANG(C++)
+acx_pthread_ok=no
+
+# We used to check for pthread.h first, but this fails if pthread.h
+# requires special compiler flags (e.g. on True64 or Sequent).
+# It gets checked for in the link test anyway.
+
+# First of all, check if the user has set any of the PTHREAD_LIBS,
+# etcetera environment variables, and if threads linking works using
+# them:
+if test x"$PTHREAD_LIBS$PTHREAD_CXXFLAGS" != x; then
+ save_CXXFLAGS="$CXXFLAGS"
+ CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+ save_LIBS="$LIBS"
+ LIBS="$PTHREAD_LIBS $LIBS"
+ AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CXXFLAGS=$PTHREAD_CXXFLAGS])
+ AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
+ AC_MSG_RESULT($acx_pthread_ok)
+ if test x"$acx_pthread_ok" = xno; then
+ PTHREAD_LIBS=""
+ PTHREAD_CXXFLAGS=""
+ fi
+ LIBS="$save_LIBS"
+ CXXFLAGS="$save_CXXFLAGS"
+fi
+
+# We must check for the threads library under a number of different
+# names; the ordering is very important because some systems
+# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
+# libraries is broken (non-POSIX).
+
+# Create a list of thread flags to try. Items starting with a "-" are
+# C compiler flags, and other items are library names, except for "none"
+# which indicates that we try without any flags at all, and "pthread-config"
+# which is a program returning the flags for the Pth emulation library.
+
+# CS: On GNU/Linux with gcc both -pthread and -lpthread are valid.
+# However, libtool links libraries with -nostdlib which results in
+# -pthread being stripped from the linker command line. To resolve
+# this we move pthread from after -mthreads to after pthreads.
+#
+acx_pthread_flags="pthreads pthread none -Kthread -kthread lthread -pthread -pthreads -mthreads --thread-safe -mt pthread-config"
+
+# The ordering *is* (sometimes) important. Some notes on the
+# individual items follow:
+
+# pthreads: AIX (must check this before -lpthread)
+# none: in case threads are in libc; should be tried before -Kthread and
+# other compiler flags to prevent continual compiler warnings
+# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
+# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
+# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
+# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
+# -pthreads: Solaris/gcc
+# -mthreads: Mingw32/gcc, Lynx/gcc
+# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
+# doesn't hurt to check since this sometimes defines pthreads too;
+# also defines -D_REENTRANT)
+# ... -mt is also the pthreads flag for HP/aCC
+# pthread: Linux, etcetera
+# --thread-safe: KAI C++
+# pthread-config: use pthread-config program (for GNU Pth library)
+
+case "${host_cpu}-${host_os}" in
+ *solaris*)
+
+ # On Solaris (at least, for some versions), libc contains stubbed
+ # (non-functional) versions of the pthreads routines, so link-based
+ # tests will erroneously succeed. (We need to link with -pthreads/-mt/
+ # -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
+ # a function called by this macro, so we could check for that, but
+ # who knows whether they'll stub that too in a future libc.) So,
+ # we'll just look for -pthreads and -lpthread first:
+
+ acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
+ ;;
+esac
+
+if test x"$acx_pthread_ok" = xno; then
+for flag in $acx_pthread_flags; do
+
+ case $flag in
+ none)
+ AC_MSG_CHECKING([whether pthreads work without any flags])
+ ;;
+
+ -*)
+ AC_MSG_CHECKING([whether pthreads work with $flag])
+ PTHREAD_CXXFLAGS="$flag"
+ ;;
+
+ pthread-config)
+ AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
+ if test x"$acx_pthread_config" = xno; then continue; fi
+ PTHREAD_CXXFLAGS="`pthread-config --cflags`"
+ PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
+ ;;
+
+ *)
+ AC_MSG_CHECKING([for the pthreads library -l$flag])
+ PTHREAD_LIBS="-l$flag"
+ ;;
+ esac
+
+ save_LIBS="$LIBS"
+ save_CXXFLAGS="$CXXFLAGS"
+ LIBS="$PTHREAD_LIBS $LIBS"
+ CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+ # Check for various functions. We must include pthread.h,
+ # since some functions may be macros. (On the Sequent, we
+ # need a special flag -Kthread to make this header compile.)
+ # We check for pthread_join because it is in -lpthread on IRIX
+ # while pthread_create is in libc. We check for pthread_attr_init
+ # due to DEC craziness with -lpthreads. We check for
+ # pthread_cleanup_push because it is one of the few pthread
+ # functions on Solaris that doesn't have a non-functional libc stub.
+ # We try pthread_create on general principles.
+ #
+ AC_TRY_LINK([#include <pthread.h>],
+ [pthread_t th; pthread_join(th, 0);
+ pthread_attr_init(0); pthread_cleanup_push(0, 0);
+ pthread_create(0,0,0,0); pthread_cleanup_pop(0);],
+ [acx_pthread_ok=yes])
+
+ LIBS="$save_LIBS"
+ CXXFLAGS="$save_CXXFLAGS"
+
+ AC_MSG_RESULT($acx_pthread_ok)
+ if test "x$acx_pthread_ok" = xyes; then
+ break;
+ fi
+
+ PTHREAD_LIBS=""
+ PTHREAD_CXXFLAGS=""
+done
+fi
+
+# Various other checks:
+if test "x$acx_pthread_ok" = xyes; then
+ save_LIBS="$LIBS"
+ LIBS="$PTHREAD_LIBS $LIBS"
+ save_CXXFLAGS="$CXXFLAGS"
+ CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+dnl # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
+dnl AC_MSG_CHECKING([for joinable pthread attribute])
+dnl attr_name=unknown
+dnl for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
+dnl AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
+dnl [attr_name=$attr; break])
+dnl done
+dnl AC_MSG_RESULT($attr_name)
+dnl if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
+dnl AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
+dnl [Define to necessary symbol if this constant
+dnl uses a non-standard name on your system.])
+dnl fi
+
+ AC_MSG_CHECKING([if more special flags are required for pthreads])
+ flag=no
+ case "${host_cpu}-${host_os}" in
+ *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
+ *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
+ esac
+ AC_MSG_RESULT(${flag})
+ if test "x$flag" != xno; then
+ PTHREAD_CXXFLAGS="$flag $PTHREAD_CXXFLAGS"
+ fi
+
+ LIBS="$save_LIBS"
+ CXXFLAGS="$save_CXXFLAGS"
+
+dnl # More AIX lossage: must compile with xlC_r
+dnl if test x"$GXX" != xyes; then
+dnl AC_CHECK_PROGS(PTHREAD_CXX, xlC_r, ${CXX})
+dnl else
+dnl PTHREAD_CXX=$CXX
+dnl fi
+
+else
+ PTHREAD_CXX="$CXX"
+fi
+
+AC_SUBST(PTHREAD_LIBS)
+AC_SUBST(PTHREAD_CXXFLAGS)
+AC_SUBST(PTHREAD_CXX)
+
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
+if test x"$acx_pthread_ok" = xyes; then
+ ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
+ :
+else
+ acx_pthread_ok=no
+ $2
+fi
+AC_LANG_RESTORE
+])dnl ACX_PTHREAD
diff --git a/m4/database.m4 b/m4/database.m4
new file mode 100644
index 0000000..8fca493
--- /dev/null
+++ b/m4/database.m4
@@ -0,0 +1,41 @@
+dnl file : m4/database.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl DATABASE
+dnl
+AC_DEFUN([DATABASE], [
+database=none
+
+AC_MSG_CHECKING([for database to use])
+
+AC_ARG_WITH(
+ [database],
+ [AC_HELP_STRING([--with-database=db],
+ [database to use for tests; valid values are: 'mysql'])],
+ [case $withval in
+ no | yes)
+ AC_MSG_RESULT([])
+ AC_MSG_ERROR([no database specified in the --with-database option])
+ ;;
+ mysql)
+ database=mysql
+ AC_DEFINE([DB_ID_MYSQL], [1], [Using MySQL.])
+ ;;
+ *)
+ AC_MSG_RESULT([])
+ AC_MSG_ERROR([unknown database $withval])
+ ;;
+ esac],
+ [
+ AC_MSG_RESULT([])
+ AC_MSG_ERROR([no database specified with the --with-database option])
+ ])
+
+AC_MSG_RESULT([$database])
+AC_SUBST([database])
+
+AM_CONDITIONAL([DB_ID_MYSQL], [test x$database = xmysql])
+
+])dnl
diff --git a/m4/diff.m4 b/m4/diff.m4
new file mode 100644
index 0000000..5401748
--- /dev/null
+++ b/m4/diff.m4
@@ -0,0 +1,55 @@
+dnl file : m4/diff.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl DIFF_TOOL
+dnl
+AC_DEFUN([DIFF_TOOL], [
+diff_found=no
+
+AC_ARG_VAR([DIFF],[diff command])
+AC_ARG_VAR([DIFFFLAGS],[diff flags])
+
+AC_ARG_WITH(
+ [diff],
+ [AC_HELP_STRING([--with-diff=PATH],[path to the diff program])],
+ [diff_path=${withval}],
+ [diff_path=])
+
+AC_MSG_CHECKING([for diff])
+
+if test x"$DIFF" = x; then
+ if test x"$diff_path" != x; then
+ AS_SET_CATFILE([abs_diff_path], [$ac_pwd], [$diff_path])
+ DIFF="$abs_diff_path"
+ else
+ DIFF=diff
+ fi
+fi
+
+cat >conftest.txt
+
+$DIFF conftest.txt conftest.txt 2>/dev/null 1>&2
+
+if test x"$?" = x0; then
+ AC_MSG_RESULT([$DIFF])
+else
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([diff command is not found; consider setting the DIFF variable or using --with-diff=PATH])
+fi
+
+AC_MSG_CHECKING([whether $DIFF accepts -u])
+
+$DIFF -u conftest.txt conftest.txt 2>/dev/null 1>&2
+
+if test x"$?" = x0; then
+ AC_MSG_RESULT([yes])
+ DIFFFLAGS="$DIFFFLAGS -u"
+else
+ AC_MSG_RESULT([no])
+fi
+
+rm -f conftest.txt
+
+])dnl
diff --git a/m4/libodb-mysql.m4 b/m4/libodb-mysql.m4
new file mode 100644
index 0000000..13e3ff3
--- /dev/null
+++ b/m4/libodb-mysql.m4
@@ -0,0 +1,84 @@
+dnl file : m4/libodb-mysql.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBODB_MYSQL([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBODB_MYSQL], [
+libodb_mysql_found=no
+
+AC_ARG_WITH(
+ [libodb-mysql],
+ [AC_HELP_STRING([--with-libodb-mysql=DIR],[location of libodb-mysql build directory])],
+ [libodb_mysql_dir=${withval}],
+ [libodb_mysql_dir=])
+
+AC_MSG_CHECKING([for libodb-mysql])
+
+# If libodb_mysql_dir was given, add the necessary preprocessor and
+# linker flags.
+#
+if test x"$libodb_mysql_dir" != x; then
+ save_CPPFLAGS="$CPPFLAGS"
+ save_LDFLAGS="$LDFLAGS"
+
+ AS_SET_CATFILE([abs_libodb_mysql_dir], [$ac_pwd], [$libodb_mysql_dir])
+
+ CPPFLAGS="$CPPFLAGS -I$abs_libodb_mysql_dir"
+ LDFLAGS="$LDFLAGS -L$abs_libodb_mysql_dir/odb/mysql"
+fi
+
+save_LIBS="$LIBS"
+LIBS="-lodb-mysql $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <odb/mysql/exceptions.hxx>
+
+void
+f ()
+{
+}
+
+const char*
+g ()
+{
+ try
+ {
+ f ();
+ }
+ catch (const odb::mysql::database_exception& e)
+ {
+ return e.what ();
+ }
+ return 0;
+}
+
+int
+main ()
+{
+ const char* m (g ());
+ return m != 0;
+}
+]]),
+[libodb_mysql_found=yes])
+
+if test x"$libodb_mysql_found" = xno; then
+ LIBS="$save_LIBS"
+
+ if test x"$libodb_mysql_dir" != x; then
+ CPPFLAGS="$save_CPPFLAGS"
+ LDFLAGS="$save_LDFLAGS"
+ fi
+fi
+
+if test x"$libodb_mysql_found" = xyes; then
+ AC_MSG_RESULT([yes])
+ $1
+else
+ AC_MSG_RESULT([no])
+ $2
+fi
+])dnl
diff --git a/m4/libodb-tracer.m4 b/m4/libodb-tracer.m4
new file mode 100644
index 0000000..bd7a371
--- /dev/null
+++ b/m4/libodb-tracer.m4
@@ -0,0 +1,84 @@
+dnl file : m4/libodb-tracer.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBODB_TRACER([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBODB_TRACER], [
+libodb_tracer_found=no
+
+AC_ARG_WITH(
+ [libodb-tracer],
+ [AC_HELP_STRING([--with-libodb-tracer=DIR],[location of libodb-tracer build directory])],
+ [libodb_tracer_dir=${withval}],
+ [libodb_tracer_dir=])
+
+AC_MSG_CHECKING([for libodb-tracer])
+
+# If libodb_tracer_dir was given, add the necessary preprocessor and
+# linker flags.
+#
+if test x"$libodb_tracer_dir" != x; then
+ save_CPPFLAGS="$CPPFLAGS"
+ save_LDFLAGS="$LDFLAGS"
+
+ AS_SET_CATFILE([abs_libodb_tracer_dir], [$ac_pwd], [$libodb_tracer_dir])
+
+ CPPFLAGS="$CPPFLAGS -I$abs_libodb_tracer_dir"
+ LDFLAGS="$LDFLAGS -L$abs_libodb_tracer_dir/odb/tracer"
+fi
+
+save_LIBS="$LIBS"
+LIBS="-lodb-tracer $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <odb/tracer/exceptions.hxx>
+
+void
+f ()
+{
+}
+
+const char*
+g ()
+{
+ try
+ {
+ f ();
+ }
+ catch (const odb::tracer::database_exception& e)
+ {
+ return e.what ();
+ }
+ return 0;
+}
+
+int
+main ()
+{
+ const char* m (g ());
+ return m != 0;
+}
+]]),
+[libodb_tracer_found=yes])
+
+if test x"$libodb_tracer_found" = xno; then
+ LIBS="$save_LIBS"
+
+ if test x"$libodb_tracer_dir" != x; then
+ CPPFLAGS="$save_CPPFLAGS"
+ LDFLAGS="$save_LDFLAGS"
+ fi
+fi
+
+if test x"$libodb_tracer_found" = xyes; then
+ AC_MSG_RESULT([yes])
+ $1
+else
+ AC_MSG_RESULT([no])
+ $2
+fi
+])dnl
diff --git a/m4/libodb.m4 b/m4/libodb.m4
new file mode 100644
index 0000000..a205afd
--- /dev/null
+++ b/m4/libodb.m4
@@ -0,0 +1,83 @@
+dnl file : m4/libodb.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBODB([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBODB], [
+libodb_found=no
+
+AC_ARG_WITH(
+ [libodb],
+ [AC_HELP_STRING([--with-libodb=DIR],[location of libodb build directory])],
+ [libodb_dir=${withval}],
+ [libodb_dir=])
+
+AC_MSG_CHECKING([for libodb])
+
+# If libodb_dir was given, add the necessary preprocessor and linker flags.
+#
+if test x"$libodb_dir" != x; then
+ save_CPPFLAGS="$CPPFLAGS"
+ save_LDFLAGS="$LDFLAGS"
+
+ AS_SET_CATFILE([abs_libodb_dir], [$ac_pwd], [$libodb_dir])
+
+ CPPFLAGS="$CPPFLAGS -I$abs_libodb_dir"
+ LDFLAGS="$LDFLAGS -L$abs_libodb_dir/odb"
+fi
+
+save_LIBS="$LIBS"
+LIBS="-lodb $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <odb/exception.hxx>
+
+void
+f ()
+{
+}
+
+const char*
+g ()
+{
+ try
+ {
+ f ();
+ }
+ catch (const odb::exception& e)
+ {
+ return e.what ();
+ }
+ return 0;
+}
+
+int
+main ()
+{
+ const char* m (g ());
+ return m != 0;
+}
+]]),
+[libodb_found=yes])
+
+if test x"$libodb_found" = xno; then
+ LIBS="$save_LIBS"
+
+ if test x"$libodb_dir" != x; then
+ CPPFLAGS="$save_CPPFLAGS"
+ LDFLAGS="$save_LDFLAGS"
+ fi
+fi
+
+if test x"$libodb_found" = xyes; then
+ AC_MSG_RESULT([yes])
+ $1
+else
+ AC_MSG_RESULT([no])
+ $2
+fi
+])dnl
diff --git a/m4/libtool-link.m4 b/m4/libtool-link.m4
new file mode 100644
index 0000000..229b270
--- /dev/null
+++ b/m4/libtool-link.m4
@@ -0,0 +1,31 @@
+dnl file : m4/libtool-link.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl
+dnl CXX_LIBTOOL_LINK_IFELSE (input, [action-if-true], [action-if-false])
+dnl
+dnl Similar to AC_LINK_IFELSE except it uses libtool to perform the
+dnl linking and it does this using the C++ compiler.
+dnl
+AC_DEFUN([CXX_LIBTOOL_LINK_IFELSE],[
+AC_LANG_SAVE
+save_CXX="$CXX"
+CXX="./libtool --tag=CXX --mode=link $CXX -no-install"
+AC_LANG(C++)
+
+if test -d .libs; then
+ delete_libs_dir=no
+else
+ delete_libs_dir=yes
+fi
+
+AC_LINK_IFELSE([$1], [$2], [$3])
+
+if test x"$delete_libs_dir" != xyes; then
+ rm -rf .libs
+fi
+
+CXX="$save_CXX"
+AC_LANG_RESTORE])dnl
diff --git a/m4/mysql.m4 b/m4/mysql.m4
new file mode 100644
index 0000000..f40ba6d
--- /dev/null
+++ b/m4/mysql.m4
@@ -0,0 +1,270 @@
+dnl file : m4/mysql.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl MYSQL
+dnl
+AC_DEFUN([MYSQL], [
+
+# Client.
+#
+AC_MSG_CHECKING([for mysql client program])
+AC_ARG_WITH(
+ [mysql-client],
+ [AC_HELP_STRING([--with-mysql-client=path], [MySQL client program path (mysql by default)])],
+ [case $withval in
+ yes)
+ mysql_client=mysql
+ ;;
+ no)
+ AC_MSG_RESULT([])
+ AC_MSG_ERROR([need mysql client to run the tests])
+ ;;
+ *)
+ mysql_client=$withval
+ ;;
+ esac],
+ [mysql_client=mysql])
+
+$mysql_client --version 2>/dev/null 1>&2
+
+if test x"$?" = x0; then
+ AC_MSG_RESULT([$mysql_client])
+else
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([mysql client is not found; consider using --with-mysql-client=PATH])
+fi
+
+# User.
+#
+AC_MSG_CHECKING([for mysql database user])
+AC_ARG_WITH(
+ [mysql-user],
+ [AC_HELP_STRING([--with-mysql-user=login], [MySQL database user (odb_test by default)])],
+ [case $withval in
+ yes)
+ mysql_user=odb_test
+ mysql_user_set=yes
+ ;;
+ no)
+ mysql_user_set=no
+ ;;
+ *)
+ mysql_user=$withval
+ mysql_user_set=yes
+ ;;
+ esac],
+ [mysql_user=odb_test
+ mysql_user_set=yes])
+
+if test x$mysql_user_set = xyes; then
+ AC_MSG_RESULT(['$mysql_user'])
+else
+ AC_MSG_RESULT([none])
+fi
+
+# Password.
+#
+AC_MSG_CHECKING([for mysql database password])
+AC_ARG_WITH(
+ [mysql-password],
+ [AC_HELP_STRING([--with-mysql-password=login], [MySQL database password (no password by default)])],
+ [case $withval in
+ yes)
+ mysql_password=
+ mysql_password_set=yes
+ ;;
+ no)
+ mysql_password_set=no
+ ;;
+ *)
+ mysql_password=$withval
+ mysql_password_set=yes
+ ;;
+ esac],
+ [mysql_password_set=no])
+
+if test x$mysql_password_set = xyes; then
+ AC_MSG_RESULT(['$mysql_password'])
+else
+ AC_MSG_RESULT([none])
+fi
+
+# Database name.
+#
+AC_MSG_CHECKING([for mysql database name])
+AC_ARG_WITH(
+ [mysql-db],
+ [AC_HELP_STRING([--with-mysql-db=name], [MySQL database name (odb_test by default). Note that all data in this database WILL BE LOST!])],
+ [case $withval in
+ yes)
+ mysql_db=odb_test
+ mysql_db_set=yes
+ ;;
+ no)
+ mysql_db_set=no
+ ;;
+ *)
+ mysql_db=$withval
+ mysql_db_set=yes
+ ;;
+ esac],
+ [mysql_db=odb_test
+ mysql_db_set=yes])
+
+if test x$mysql_db_set = xyes; then
+ AC_MSG_RESULT(['$mysql_db'])
+else
+ AC_MSG_RESULT([none])
+fi
+
+# Host.
+#
+AC_MSG_CHECKING([for mysql database host])
+AC_ARG_WITH(
+ [mysql-host],
+ [AC_HELP_STRING([--with-mysql-host=host], [MySQL database host (localhost by default)])],
+ [case $withval in
+ yes)
+ mysql_host=localhost
+ mysql_host_set=yes
+ ;;
+ no)
+ mysql_host_set=no
+ ;;
+ *)
+ mysql_host=$withval
+ mysql_host_set=yes
+ ;;
+ esac],
+ [mysql_host_set=no])
+
+if test x$mysql_host_set = xyes; then
+ AC_MSG_RESULT(['$mysql_host'])
+else
+ AC_MSG_RESULT([localhost])
+fi
+
+# Port.
+#
+AC_MSG_CHECKING([for mysql database port])
+AC_ARG_WITH(
+ [mysql-port],
+ [AC_HELP_STRING([--with-mysql-port=port], [MySQL database port (standard MySQL port by default)])],
+ [case $withval in
+ yes)
+ mysql_port=0
+ mysql_port_set=yes
+ ;;
+ no)
+ mysql_port_set=no
+ ;;
+ *)
+ mysql_port=$withval
+ mysql_port_set=yes
+ ;;
+ esac],
+ [mysql_port_set=no])
+
+if test x$mysql_port_set = xyes; then
+ AC_MSG_RESULT(['$mysql_port'])
+else
+ AC_MSG_RESULT([default])
+fi
+
+# Socket.
+#
+AC_MSG_CHECKING([for mysql database socket])
+AC_ARG_WITH(
+ [mysql-socket],
+ [AC_HELP_STRING([--with-mysql-socket=socket], [MySQL database socket (standard MySQL socket by default)])],
+ [case $withval in
+ yes)
+ mysql_socket=
+ mysql_socket_set=yes
+ ;;
+ no)
+ mysql_socket_set=no
+ ;;
+ *)
+ mysql_socket=$withval
+ mysql_socket_set=yes
+ ;;
+ esac],
+ [mysql_socket_set=no])
+
+if test x$mysql_socket_set = xyes; then
+ AC_MSG_RESULT(['$mysql_socket'])
+else
+ AC_MSG_RESULT([default])
+fi
+
+# Create options file.
+#
+AC_CONFIG_COMMANDS([db.options],
+ [
+ rm -f db.options
+ echo '#! /bin/sh' >db-driver
+
+ if test x$mysql_user_set = xyes; then
+ echo "--user '$mysql_user'" >>db.options
+ echo 'opt="$opt --user='"$mysql_user"'"' >>db-driver
+ fi
+
+ if test x$mysql_password_set = xyes; then
+ echo "--passwd '$mysql_password'" >>db.options
+ echo 'opt="$opt --password='"$mysql_password"'"' >>db-driver
+ fi
+
+ if test x$mysql_db_set = xyes; then
+ echo "--db-name '$mysql_db'" >>db.options
+ echo 'opt="$opt --database='"$mysql_db"'"' >>db-driver
+ fi
+
+ if test x$mysql_host_set = xyes; then
+ echo "--host '$mysql_host'" >>db.options
+ echo 'opt="$opt --host='"$mysql_host"'"' >>db-driver
+ fi
+
+ if test x$mysql_port_set = xyes; then
+ echo "--port '$mysql_port'" >>db.options
+ echo 'opt="$opt --port='"$mysql_port"'"' >>db-driver
+ fi
+
+ if test x$mysql_socket_set = xyes; then
+ echo "--socket '$mysql_socket'" >>db.options
+ echo 'opt="$opt --socket='"$mysql_socket"'"' >>db-driver
+ fi
+
+ echo 'if test x$[]1 != x; then' >>db-driver
+ echo " exec $mysql_client "'$opt <$[]1' >>db-driver
+ echo "else" >>db-driver
+ echo " exec $mysql_client "'$opt' >>db-driver
+ echo "fi" >>db-driver
+
+ chmod +x db-driver
+ ],
+ [
+ mysql_client="$mysql_client"
+
+ mysql_user="$mysql_user"
+ mysql_user_set="$mysql_user_set"
+
+ mysql_password="$mysql_password"
+ mysql_password_set="$mysql_password_set"
+
+ mysql_db="$mysql_db"
+ mysql_db_set="$mysql_db_set"
+
+ mysql_host="$mysql_host"
+ mysql_host_set="$mysql_host_set"
+
+ mysql_port="$mysql_port"
+ mysql_port_set="$mysql_port_set"
+
+ mysql_socket="$mysql_socket"
+ mysql_socket_set="$mysql_socket_set"
+ ])
+
+])dnl
diff --git a/m4/odb.m4 b/m4/odb.m4
new file mode 100644
index 0000000..b632f8c
--- /dev/null
+++ b/m4/odb.m4
@@ -0,0 +1,45 @@
+dnl file : m4/odb.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl ODB_COMPILER([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+AC_DEFUN([ODB_COMPILER], [
+odb_found=no
+
+AC_ARG_VAR([ODB],[ODB compiler command])
+AC_ARG_VAR([ODBFLAGS],[ODB compiler flags])
+AC_ARG_VAR([ODBCPPFLAGS],[ODB-specific C++ preprocessor flags])
+
+AC_ARG_WITH(
+ [odb],
+ [AC_HELP_STRING([--with-odb=DIR],[location of odb build directory])],
+ [odb_dir=${withval}],
+ [odb_dir=])
+
+AC_MSG_CHECKING([for odb])
+
+save_ODB="$ODB"
+
+if test x"$ODB" = x; then
+ if test x"$odb_dir" != x; then
+ AS_SET_CATFILE([abs_odb_dir], [$ac_pwd], [$odb_dir])
+ ODB="$abs_odb_dir/odb/odb"
+ else
+ ODB=odb
+ fi
+fi
+
+$ODB --version 2>/dev/null 1>&2
+
+if test x"$?" = x0; then
+ AC_MSG_RESULT([$ODB])
+ $1
+else
+ AC_MSG_RESULT([no])
+ ODB="$save_ODB"
+ $2
+fi
+
+])dnl
diff --git a/m4/static-lib.m4 b/m4/static-lib.m4
new file mode 100644
index 0000000..1c0af42
--- /dev/null
+++ b/m4/static-lib.m4
@@ -0,0 +1,19 @@
+dnl file : m4/static-lib.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl STATIC_LIB(MACRO, DESCRIPTION)
+dnl
+dnl Define MACRO if we are on MinGW and are only building static library.
+dnl
+AC_DEFUN([STATIC_LIB],
+[
+if test x$enable_shared = xno; then
+ case $host_os in
+ mingw*)
+ AC_DEFINE([$1], [1], [$2])
+ ;;
+ esac
+fi
+])dnl
diff --git a/m4/threads.m4 b/m4/threads.m4
new file mode 100644
index 0000000..7c32abe
--- /dev/null
+++ b/m4/threads.m4
@@ -0,0 +1,41 @@
+dnl file : m4/threads.m4
+dnl author : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license : GNU GPL v2; see accompanying LICENSE file
+dnl
+AC_DEFUN([THREADS],[
+
+AC_ARG_ENABLE(
+ [threads],
+ AS_HELP_STRING([--disable-threads], [disable threads (enabled by default)]),
+ [AS_IF([test x"$enableval" = xno], [threads=none], [threads=check])],
+ [threads=check])
+
+# If thread support is not disabled by the user, figure out what we can use.
+#
+if test x$threads = xcheck; then
+ case $host_os in
+ windows* | mingw*)
+ case $host_os in
+ mingw*)
+ CXXFLAGS="$CXXFLAGS -mthreads"
+ ;;
+ esac
+ threads=win32
+ ;;
+ *)
+ ACX_PTHREAD
+
+ if test x$acx_pthread_ok = xyes; then
+ threads=posix
+ LIBS="$LIBS $PTHREAD_LIBS"
+ CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+ fi
+ ;;
+ esac
+fi
+
+if test x$threads = xcheck; then
+ AC_MSG_ERROR([thread support not available; use --disable-threads to force single-threaded mode])
+fi
+])dnl
generated by cgit v1.1 at 2024-11-01 11:21:15 +0000