From bc54b4bd56c757ec1279896b8b0639a4a9a7e0cd Mon Sep 17 00:00:00 2001
From: Constantin Michael <constantin@codesynthesis.com>
Date: Wed, 4 May 2011 17:17:59 +0200
Subject: Add test infrastructure for libodb-pgsql

---
 pgsql/test.bat | 70 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 pgsql/test.bat

(limited to 'pgsql/test.bat')

diff --git a/pgsql/test.bat b/pgsql/test.bat
new file mode 100644
index 0000000..4075d5c
--- /dev/null
+++ b/pgsql/test.bat
@@ -0,0 +1,70 @@
+@echo off
+rem file      : pgsql/test.bat
+rem author    : Constantin Michael <constantin@codesynthesis.com>
+rem copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+rem license   : GNU GPL v2; see accompanying LICENSE file
+
+setlocal
+
+set "tests=__path__(dirs)"
+set "confs=__path__(configurations)"
+set "plats=__path__(platforms)"
+set "curdir=%CD%"
+set "topdir=%curdir%\.."
+set "failed="
+
+goto start
+
+rem
+rem %1 - test directory
+rem %2 - configuration
+rem %3 - platform
+rem
+:run_test
+  cd %1
+
+  if "_%3_" == "_Win32_" (
+    set "dir=%2"
+  ) else (
+    set "dir=%3\%2"
+  )
+
+  if exist %dir%\driver.exe (
+    echo %1\%3\%2
+    call %topdir%\tester.bat pgsql %2 %3
+    if errorlevel 1 (
+      set "failed=%failed% %1\%3\%2"
+    )
+  )
+
+  cd %curdir%
+goto :eof
+
+:start
+
+for %%t in (%tests%) do (
+  for %%c in (%confs%) do (
+    for %%p in (%plats%) do (
+      call :run_test %%t %%c %%p
+    )
+  )
+)
+
+if not "_%failed%_" == "__" goto error
+
+echo.
+echo ALL TESTS PASSED
+echo.
+goto end
+
+:error
+if not "_%failed%_" == "__" (
+  echo.
+  for %%t in (%failed%) do echo FAILED: %%t
+  echo.
+)
+endlocal
+exit /b 1
+
+:end
+endlocal
-- 
cgit v1.1