mysql-driver.bat


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

@echo off
rem file      : mysql-driver.bat
rem author    : Boris Kolpackov <boris@codesynthesis.com>
rem copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
rem license   : GNU GPL v2; see accompanying LICENSE file

rem
rem mysql-driver.bat sql-file
rem
rem Run the mysql client on the SQL file specified. Adjust the
rem option below to match your MySQL setup.
rem

setlocal

set "options=%MYSQL_OPTIONS%"
set "options=%options% --user=odb_test"
set "options=%options% --database=odb_test"
rem set "options=%options% --password="
rem set "options=%options% --host="
rem set "options=%options% --post="
rem set "options=%options% --socket="

set "mysql=%MYSQL_CLIENT%"

if "_%mysql%_" == "__" set "mysql=mysql"

if "_%1_" == "__" (
  echo no sql file specified
  goto usage
)

%mysql% %options% < %1

if errorlevel 1 goto error
goto end

:usage
echo.
echo usage: mysql-driver.bat sql-file
echo.

:error
endlocal
exit /b 1

:end
endlocal