Add libodb-pgsql infrastructure files

8 files changed, 591 insertions, 0 deletions

diff --git a/m4/acx-pthread.m4 b/m4/acx-pthread.m4
new file mode 100644
index 0000000..ffa3dfa
--- /dev/null
+++ b/m4/acx-pthread.m4
@@ -0,0 +1,257 @@
+dnl
+dnl NOTE: This file was modified. See the comments starting with 'CS:'
+dnl for more information. In particular, it was changed to use C++
+dnl instead of C.
+dnl
+dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl @summary figure out how to build C++ programs using POSIX threads
+dnl
+dnl This macro figures out how to build C++ programs using POSIX threads.
+dnl It sets the PTHREAD_LIBS output variable to the threads library and
+dnl linker flags, and the PTHREAD_CXXFLAGS output variable to any special
+dnl C++ compiler flags that are needed. (The user can also force certain
+dnl compiler flags/libs to be tested by setting these environment
+dnl variables.)
+dnl
+dnl Also sets PTHREAD_CXX to any special C++ compiler that is needed for
+dnl multi-threaded programs (defaults to the value of CXX otherwise).
+dnl (This is necessary on AIX to use the special xlC_r compiler alias.)
+dnl
+dnl NOTE: You are assumed to not only compile your program with these
+dnl flags, but also link it with them as well. e.g. you should link
+dnl with $PTHREAD_CXX $CXXFLAGS $PTHREAD_CXXFLAGS $LDFLAGS ... $PTHREAD_LIBS
+dnl $LIBS
+dnl
+dnl If you are only building threads programs, you may wish to use
+dnl these variables in your default LIBS, CXXFLAGS, and CXX:
+dnl
+dnl        LIBS="$PTHREAD_LIBS $LIBS"
+dnl        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+dnl        CXX="$PTHREAD_CXX"
+dnl
+dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
+dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
+dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
+dnl
+dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
+dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
+dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
+dnl default action will define HAVE_PTHREAD.
+dnl
+dnl Please let the authors know if this macro fails on any platform, or
+dnl if you have any other suggestions or comments. This macro was based
+dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
+dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
+dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
+dnl We are also grateful for the helpful feedback of numerous users.
+dnl
+dnl @category InstalledPackages
+dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
+dnl @version 2006-05-29
+dnl @license GPLWithACException
+
+AC_DEFUN([ACX_PTHREAD], [
+AC_REQUIRE([AC_CANONICAL_HOST])
+AC_LANG_SAVE
+AC_LANG(C++)
+acx_pthread_ok=no
+
+# We used to check for pthread.h first, but this fails if pthread.h
+# requires special compiler flags (e.g. on True64 or Sequent).
+# It gets checked for in the link test anyway.
+
+# First of all, check if the user has set any of the PTHREAD_LIBS,
+# etcetera environment variables, and if threads linking works using
+# them:
+if test x"$PTHREAD_LIBS$PTHREAD_CXXFLAGS" != x; then
+        save_CXXFLAGS="$CXXFLAGS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+        save_LIBS="$LIBS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CXXFLAGS=$PTHREAD_CXXFLAGS])
+        AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
+        AC_MSG_RESULT($acx_pthread_ok)
+        if test x"$acx_pthread_ok" = xno; then
+                PTHREAD_LIBS=""
+                PTHREAD_CXXFLAGS=""
+        fi
+        LIBS="$save_LIBS"
+        CXXFLAGS="$save_CXXFLAGS"
+fi
+
+# We must check for the threads library under a number of different
+# names; the ordering is very important because some systems
+# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
+# libraries is broken (non-POSIX).
+
+# Create a list of thread flags to try.  Items starting with a "-" are
+# C compiler flags, and other items are library names, except for "none"
+# which indicates that we try without any flags at all, and "pthread-config"
+# which is a program returning the flags for the Pth emulation library.
+
+# CS: On GNU/Linux with gcc both -pthread and -lpthread are valid.
+# However, libtool links libraries with -nostdlib which results in
+# -pthread being stripped from the linker command line. To resolve
+# this we move pthread from after -mthreads to after pthreads.
+#
+acx_pthread_flags="pthreads pthread none -Kthread -kthread lthread -pthread -pthreads -mthreads --thread-safe -mt pthread-config"
+
+# The ordering *is* (sometimes) important.  Some notes on the
+# individual items follow:
+
+# pthreads: AIX (must check this before -lpthread)
+# none: in case threads are in libc; should be tried before -Kthread and
+#       other compiler flags to prevent continual compiler warnings
+# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
+# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
+# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
+# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
+# -pthreads: Solaris/gcc
+# -mthreads: Mingw32/gcc, Lynx/gcc
+# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
+#      doesn't hurt to check since this sometimes defines pthreads too;
+#      also defines -D_REENTRANT)
+#      ... -mt is also the pthreads flag for HP/aCC
+# pthread: Linux, etcetera
+# --thread-safe: KAI C++
+# pthread-config: use pthread-config program (for GNU Pth library)
+
+case "${host_cpu}-${host_os}" in
+        *solaris*)
+
+        # On Solaris (at least, for some versions), libc contains stubbed
+        # (non-functional) versions of the pthreads routines, so link-based
+        # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
+        # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
+        # a function called by this macro, so we could check for that, but
+        # who knows whether they'll stub that too in a future libc.)  So,
+        # we'll just look for -pthreads and -lpthread first:
+
+        # CS: Move -mt to the front of the list; Sun CC will use -mt,
+        # gcc will use -pthreads.
+        #
+        acx_pthread_flags="-mt -pthreads pthread -pthread $acx_pthread_flags"
+        ;;
+esac
+
+if test x"$acx_pthread_ok" = xno; then
+for flag in $acx_pthread_flags; do
+
+        case $flag in
+                none)
+                AC_MSG_CHECKING([whether pthreads work without any flags])
+                ;;
+
+                -*)
+                AC_MSG_CHECKING([whether pthreads work with $flag])
+                PTHREAD_CXXFLAGS="$flag"
+                ;;
+
+		pthread-config)
+		AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
+		if test x"$acx_pthread_config" = xno; then continue; fi
+		PTHREAD_CXXFLAGS="`pthread-config --cflags`"
+		PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
+		;;
+
+                *)
+                AC_MSG_CHECKING([for the pthreads library -l$flag])
+                PTHREAD_LIBS="-l$flag"
+                ;;
+        esac
+
+        save_LIBS="$LIBS"
+        save_CXXFLAGS="$CXXFLAGS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+        # Check for various functions.  We must include pthread.h,
+        # since some functions may be macros.  (On the Sequent, we
+        # need a special flag -Kthread to make this header compile.)
+        # We check for pthread_join because it is in -lpthread on IRIX
+        # while pthread_create is in libc.  We check for pthread_attr_init
+        # due to DEC craziness with -lpthreads.  We check for
+        # pthread_cleanup_push because it is one of the few pthread
+        # functions on Solaris that doesn't have a non-functional libc stub.
+        # We try pthread_create on general principles.
+        #
+        AC_TRY_LINK([#include <pthread.h>],
+                    [pthread_t th; pthread_join(th, 0);
+                     pthread_attr_init(0); pthread_cleanup_push(0, 0);
+                     pthread_create(0,0,0,0); pthread_cleanup_pop(0);],
+                    [acx_pthread_ok=yes])
+
+        LIBS="$save_LIBS"
+        CXXFLAGS="$save_CXXFLAGS"
+
+        AC_MSG_RESULT($acx_pthread_ok)
+        if test "x$acx_pthread_ok" = xyes; then
+                break;
+        fi
+
+        PTHREAD_LIBS=""
+        PTHREAD_CXXFLAGS=""
+done
+fi
+
+# Various other checks:
+if test "x$acx_pthread_ok" = xyes; then
+        save_LIBS="$LIBS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        save_CXXFLAGS="$CXXFLAGS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+dnl     # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
+dnl	AC_MSG_CHECKING([for joinable pthread attribute])
+dnl	attr_name=unknown
+dnl	for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
+dnl	    AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
+dnl                        [attr_name=$attr; break])
+dnl	done
+dnl     AC_MSG_RESULT($attr_name)
+dnl     if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
+dnl         AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
+dnl                            [Define to necessary symbol if this constant
+dnl                             uses a non-standard name on your system.])
+dnl     fi
+
+        AC_MSG_CHECKING([if more special flags are required for pthreads])
+        flag=no
+        case "${host_cpu}-${host_os}" in
+            *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
+            *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
+        esac
+        AC_MSG_RESULT(${flag})
+        if test "x$flag" != xno; then
+            PTHREAD_CXXFLAGS="$flag $PTHREAD_CXXFLAGS"
+        fi
+
+        LIBS="$save_LIBS"
+        CXXFLAGS="$save_CXXFLAGS"
+
+dnl     # More AIX lossage: must compile with xlC_r
+dnl	if test x"$GXX" != xyes; then
+dnl          AC_CHECK_PROGS(PTHREAD_CXX, xlC_r, ${CXX})
+dnl        else
+dnl          PTHREAD_CXX=$CXX
+dnl	fi
+
+else
+        PTHREAD_CXX="$CXX"
+fi
+
+AC_SUBST(PTHREAD_LIBS)
+AC_SUBST(PTHREAD_CXXFLAGS)
+AC_SUBST(PTHREAD_CXX)
+
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
+if test x"$acx_pthread_ok" = xyes; then
+        ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
+        :
+else
+        acx_pthread_ok=no
+        $2
+fi
+AC_LANG_RESTORE
+])dnl ACX_PTHREAD
diff --git a/m4/disable-rpath.m4 b/m4/disable-rpath.m4
new file mode 100644
index 0000000..376599e
--- /dev/null
+++ b/m4/disable-rpath.m4
@@ -0,0 +1,26 @@
+dnl file      : m4/disable-rpath.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+AC_DEFUN([DISABLE_RPATH],[
+
+AC_MSG_CHECKING([whether to use rpath])
+AC_ARG_ENABLE(
+  [rpath],
+  [AC_HELP_STRING([--disable-rpath], [patch libtool to not use rpath])],
+  [libtool_rpath="$enable_rpath"],
+  [libtool_rpath="yes"])
+AC_MSG_RESULT($libtool_rpath)
+
+# Patch libtool to not use rpath if requested.
+#
+AC_CONFIG_COMMANDS(
+  [libtool-rpath-patch],
+  [if test "$libtool_use_rpath" = "no"; then
+     sed < libtool > libtool-2 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_NO_RPATH__ "/'
+     mv libtool-2 libtool
+     chmod 755 libtool
+  fi],
+  [libtool_use_rpath=$libtool_rpath])
+])dnl
diff --git a/m4/libodb.m4 b/m4/libodb.m4
new file mode 100644
index 0000000..fb11859
--- /dev/null
+++ b/m4/libodb.m4
@@ -0,0 +1,83 @@
+dnl file      : m4/libodb.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBODB([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBODB], [
+libodb_found=no
+
+AC_ARG_WITH(
+  [libodb],
+  [AC_HELP_STRING([--with-libodb=DIR],[location of libodb build directory])],
+  [libodb_dir=${withval}],
+  [libodb_dir=])
+
+AC_MSG_CHECKING([for libodb])
+
+# If libodb_dir was given, add the necessary preprocessor and linker flags.
+#
+if test x"$libodb_dir" != x; then
+  save_CPPFLAGS="$CPPFLAGS"
+  save_LDFLAGS="$LDFLAGS"
+
+  AS_SET_CATFILE([abs_libodb_dir], [$ac_pwd], [$libodb_dir])
+
+  CPPFLAGS="$CPPFLAGS -I$abs_libodb_dir"
+  LDFLAGS="$LDFLAGS -L$abs_libodb_dir/odb"
+fi
+
+save_LIBS="$LIBS"
+LIBS="-lodb $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <odb/exception.hxx>
+
+void
+f ()
+{
+}
+
+const char*
+g ()
+{
+  try
+  {
+    f ();
+  }
+  catch (const odb::exception& e)
+  {
+    return e.what ();
+  }
+  return 0;
+}
+
+int
+main ()
+{
+  const char* m (g ());
+  return m != 0;
+}
+]]),
+[libodb_found=yes])
+
+if test x"$libodb_found" = xno; then
+  LIBS="$save_LIBS"
+
+  if test x"$libodb_dir" != x; then
+    CPPFLAGS="$save_CPPFLAGS"
+    LDFLAGS="$save_LDFLAGS"
+  fi
+fi
+
+if test x"$libodb_found" = xyes; then
+  AC_MSG_RESULT([yes])
+  $1
+else
+  AC_MSG_RESULT([no])
+  $2
+fi
+])dnl
diff --git a/m4/libpq.m4 b/m4/libpq.m4
new file mode 100644
index 0000000..86fd38a
--- /dev/null
+++ b/m4/libpq.m4
@@ -0,0 +1,85 @@
+dnl file      : m4/libpq.m4
+dnl author    : Constantin Michael <constantin@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBPQ([ACTION-IF-FOUND[,
+dnl       ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBPQ], [
+libpq_found=no
+
+AC_PATH_PROG([pg_config],[pg_config])
+
+AC_MSG_CHECKING([for libpq])
+
+# Check for libpq using default CPPFLAGS/LDFLAGS.
+#
+save_LIBS="$LIBS"
+LIBS="-lpq $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <libpq-fe.h>
+
+int
+main ()
+{
+  PGconn* conn = PQconnectdb ("");
+  char* dbname =  PQdb (conn);
+  PQfinish (conn);
+  return 0;
+}
+]]),
+[
+libpq_found=yes
+])
+
+if test x"$libpq_found" = xno; then
+
+  # If default CPPFLAGS/LDFLAGS didn't work, try to discover
+  # them using pg_config.
+  #
+  if test x"$libpq_found" = xno; then
+
+    if test x"$pg_config" != x; then
+      save_CPPFLAGS="$CPPFLAGS"
+
+      CPPFLAGS=-I`$pg_config --includedir`
+      CPPFLAGS="$CPPFLAGS $save_CPPFLAGS"
+
+      CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <libpq-fe.h>
+
+int
+main ()
+{
+  PGconn* conn = PQconnectdb ("");
+  char* dbname =  PQdb (conn);
+  PQfinish (conn);
+  return 0;
+}
+]]),
+[
+libpq_found=yes
+])
+
+     if test x"$libpq_found" = xno; then
+       CPPFLAGS="$save_CPPFLAGS"
+     fi
+
+    fi
+  fi
+fi
+
+if test x"$libpq_found" = xyes; then
+  AC_MSG_RESULT([yes])
+  $1
+else
+  LIBS="$save_LIBS"
+  AC_MSG_RESULT([no])
+  $2
+fi
+])dnl
diff --git a/m4/libtool-link.m4 b/m4/libtool-link.m4
new file mode 100644
index 0000000..d8395d5
--- /dev/null
+++ b/m4/libtool-link.m4
@@ -0,0 +1,47 @@
+dnl file      : m4/libtool-link.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl
+dnl CXX_LIBTOOL_LINK_IFELSE (input, [action-if-true], [action-if-false])
+dnl
+dnl Similar to AC_LINK_IFELSE except it uses libtool to perform the
+dnl linking and it does this using the C++ compiler.
+dnl
+AC_DEFUN([CXX_LIBTOOL_LINK_IFELSE],[
+AC_LANG_SAVE
+AC_LANG(C++)
+
+if test -d .libs; then
+  delete_libs_dir=no
+else
+  delete_libs_dir=yes
+fi
+
+AC_COMPILE_IFELSE([$1],
+[
+  ac_try='./libtool --tag=CXX --mode=link $CXX -no-install $CXXFLAGS $LDFLAGS -o conftest conftest.$OBJEXT $LIBS >&AS_MESSAGE_LOG_FD'
+  if _AC_DO_VAR(ac_try); then
+    libtool_link_ok=yes
+  else
+    libtool_link_ok=no
+  fi
+],
+[
+  libtool_link_ok=no
+])
+
+if test x"$delete_libs_dir" = xyes; then
+  rm -rf .libs
+fi
+
+if test x"$libtool_link_ok" = xyes; then
+[$2]
+:
+else
+[$3]
+:
+fi
+
+AC_LANG_RESTORE])dnl
diff --git a/m4/pkgconfig.m4 b/m4/pkgconfig.m4
new file mode 100644
index 0000000..11ccb00
--- /dev/null
+++ b/m4/pkgconfig.m4
@@ -0,0 +1,13 @@
+dnl file      : m4/pkgconfig.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+AC_DEFUN([PKGCONFIG],[
+AC_ARG_WITH(
+  [pkgconfigdir],
+  [AC_HELP_STRING([--with-pkgconfigdir=DIR],[location of pkgconfig dir (default is libdir/pkgconfig)])],
+  [pkgconfigdir=${withval}],
+  [pkgconfigdir='${libdir}/pkgconfig'])
+AC_SUBST([pkgconfigdir])
+])dnl
diff --git a/m4/static-lib.m4 b/m4/static-lib.m4
new file mode 100644
index 0000000..f550b7b
--- /dev/null
+++ b/m4/static-lib.m4
@@ -0,0 +1,19 @@
+dnl file      : m4/static-lib.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl STATIC_LIB(MACRO, DESCRIPTION)
+dnl
+dnl Define MACRO if we are on MinGW and are only building static library.
+dnl
+AC_DEFUN([STATIC_LIB],
+[
+if test x$enable_shared = xno; then
+  case $host_os in
+    mingw*)
+      AC_DEFINE([$1], [1], [$2])
+      ;;
+  esac
+fi
+])dnl
diff --git a/m4/threads.m4 b/m4/threads.m4
new file mode 100644
index 0000000..d4ed7cd
--- /dev/null
+++ b/m4/threads.m4
@@ -0,0 +1,61 @@
+dnl file      : m4/threads.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+AC_DEFUN([THREADS],[
+
+threads_thread_keyword=no
+
+AC_ARG_ENABLE(
+  [threads],
+  AS_HELP_STRING([--disable-threads], [disable threads (enabled by default)]),
+  [AS_IF([test x"$enableval" = xno], [threads=none], [threads=check])],
+  [threads=check])
+
+# If thread support is not disabled by the user, figure out what we can use.
+#
+if test x$threads = xcheck; then
+  case $host_os in
+    windows* | mingw*)
+      case $host_os in
+        mingw*)
+          CXXFLAGS="$CXXFLAGS -mthreads"
+          ;;
+      esac
+      threads=win32
+      ;;
+    *)
+      ACX_PTHREAD
+
+      if test x$acx_pthread_ok = xyes; then
+        threads=posix
+        LIBS="$LIBS $PTHREAD_LIBS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+        # Check if we can use the __thread keyword.
+        #
+        AC_MSG_CHECKING([for __thread keyword])
+
+        CXX_LIBTOOL_LINK_IFELSE(
+          AC_LANG_SOURCE([[
+            __thread int tls_var;
+
+            int
+            main ()
+            {
+              tls_var = 0;
+            }
+          ]]),
+          [threads_thread_keyword=yes])
+
+        AC_MSG_RESULT([$threads_thread_keyword])
+      fi
+      ;;
+  esac
+fi
+
+if test x$threads = xcheck; then
+  AC_MSG_ERROR([thread support not available; use --disable-threads to force single-threaded mode])
+fi
+])dnl